The behavioral modeling of the vertical cavity GaAs/GaAlAs lasers

Academic Open Internet Journal

ISSN 1311-4360

www.acadjournal.com

Volume 17, 2006

Simple behavioral PSPICE model of the vertical cavity GaAs/GaAlAs laser

A.Wolczko PhD

Institute of Electronics University of Science & Technology

Al.Mickiewicza 30 30-059 Krakow Poland

awolczko@uci.agh.edu.pl

Abstract: A nonlinear model of the VCSEL laser for PSPICE simulator of the electronic circuits has a form of subcircuit .SUBCKT VCSEL into input circuit file *.cir and is intended for electronic circuit design. All electrical signals and signal of optical power (represented by an equivalent voltage) are analyzed. The behavioral description of many electronic components is a commonly used method in SPICE and this way of modeling has been chosen. The complete subcircuit file for 0.85mm Lasermate VCSEL, some examples of simulations, verification measurements and final comments are contained in the paper.

Keywords : VCSEL, SPICE, behavioral modeling

1. Introduction

The model of VCSEL would be easy to application for electronic circuit designers who as a final users of lasers and other electronic components may not be familiar with intrications of laser physics. Simulation in the circuit design process would allow to analyze the mutual influences of the characteristics of the laser on the values and shapes of circuit signals and the properties of the electrical circuit on the output optical signal.

It is assumed that:

· the model would be compatible with popular versions of SPICE installed in PC computers

· the model will be defined as library file in SPICE as a subcircuit and in the main input file *.cir describing electronic circuit structure and types of analyses this library will be invoked

· commercially available VCSEL TFC-M85A4X5 from Lasermate Group [1] as a basic model component is taken

· the model would be applicable for other types of GaAs/GaAlAs VCSELs by changing some easy to measure parameters without change of the file structure.

The commonly used method of modeling of the different components in SPICE is behavioral description of the object by determining voltage, current, time and temperature relations at the external electrical nodes of the modeled component. This method of modeling VCSEL is proposed.

2. Equivalent schematic diagram.

Presented in figure 1 equivalent schematic diagram contains three modules. First passive single port (AN,KA) represents laser diode as a load for electronic driver. The second module driven by current I_RS with nodes OOU,GNO models output optical signal. The third one driven by I_RS and U_D1 allows (during transient analysis) estimation of average dissipated power in laser [2].

Fig.1. Equivalent schematic diagram of the model

From electrical point of view laser diode D1 is a singe-port component (AN,KA) with parasitic RS, L1, CL of the case. This nonlinear single-port is a one part of the bigger electrical circuit (driver) and all voltages and current in that circuit are determined by: voltage/current characteristic of the laser diode and the rest components of the circuit. In SPICE a semiconductor diode is modeled by nonlinear equation. Measurements of characteristics (static and dynamic) makes possible to find most of needed parameters. On the base of references [3] and own measurements the set of parameters for V/I characteristic of modeled diode has been matched – part of figure 2 shows the result.

Fig.2 . Simulation 1-optical power 2-AN-KA voltage

The signal of the optical power is represented in the model by a current source G_OPT at the nodes OOU-GNO (fig.1). Static characteristic P_l(I) is above threshold approximated by the 3-th order polynomial which allows well match polynomial curve to typical S shape nonlinearity of the laser ( the rising part ,most important in practical applications, of the emission characteristic 0¸P_l_max is modeled ) – see figure 2. The thermal changes of polynomial coefficients were found experimentally. The threshold current I_pr(T) is determined by equation [4]:

(1)

I_Th – minimal threshold current vs. temperature

The current source G_OPT is approximated by formula :

(2)

K – scaling factor

In the typical applications VCSEL lasers are pulse driven so that pulse tests were done using ECL driver of VCSEL presented in paper [5].

Two dynamic effects influencing on dynamics of optical power are simulated in the model [6].

Self resonance may be approximated by low pass second order filter with two complex conjugate poles. Suitable Laplace formula has been placed in circuit file.

In the case subtreshold driving (I_min<I_pr) some delay of leading edge of optical signal vs. current edge occurs. The delay lasts until the threshold concentration of carriers in the laser cavity is achieved. It is difficult to simulate such delay in electrical circuit. Two switched capacitors CE,CE1 in the model only briefly approximate the mentioned effect.

Power dissipated in the laser junction causes the rise of temperature above ambient of the diode structure because the thermal resistance junction/case is high. Parameter dT (7°C default for M85A4X5) is introduced to the model for calculations of temperature dependent values. Parameter dT may be estimated by calculation of average dissipated power multiplied by thermal resistance. Sometimes complicated shapes of voltage and current pulses can make difficult that estimation of power. The simple procedure in SPICE is helpful to obtain dT during TRANSIENT analysis. The final voltage at node TOU represents average dT and actualization of analysis is possible.

3. Subcircuit file.

The presented subcircuit model shown below.

.SUBCKT VCSEL AN KA OOU GNO TOU

* AN - VCSEL's anode

* KA - VCSEL's kathode

*GNO - gnd for sources OOU,TOU

* OOU - voltage source - represents optical power

*TOU - voltage source - represents temperature growth dT of selfheating

R_G KA 0 1E6

RS 21 20 1

D1 20 KA LVCSEL

CL 21 KA .5P

L1 AN 21 1N

.MODEL LVCSEL D Is=10E-13 EG=1.46 N=2.8 XTI=27 RS=26 TRS1=-1.25E-3

***** IMPORTANT PARAMETERS ENTERED TO THE MODEL BY USER ****

.PARAM T0=25 ITH=4.63E-3 K=390U

* K - scaling factor of the optical power

*ITH - minimal threshold current of the laser [mA]

* at temperature TO [oC]

* dT - default 7 [oC] - see below

***** OPTICAL TURN-ON DELAY OF THE LASER ****

.PARAM Z=1

*for Z=0 the calculation of optical turn-on delay is INACTIVE !!!

G_M GNO 41 21 20 1

RS1 41 40 26 TC1=-1.25E-3

RS2 40 46 1 TC1=-1.25E-3

D11 46 GNO LVCSEL1

.MODEL LVCSEL1 D Is=4E-12 EG=1.46 N=2.8 XTI=27 RS=0

CE GNO 45 5P

S1 45 40 30 GNO SWI

E_KL1 30 GNO VALUE={Z}

.MODEL SWI VSWITCH ROFF=1E4 RON=1 VOFF=0 VON=1

CE1 GNO 47 5P

S2 40 47 31 GNO SWI

E_KL2 31 GNO VALUE={IF(V(21,20)<(IPR-.5E-3),Z,0)}

* EFFECT OF THE LASER SELF-RESONANCE

.PARAM F=30G D=.2

ELAP LA GNO LAPLACE {V(40,46)}={1/(1+2*D*S/F+S**2/F**2)}

RLAP LA GNO 1E6

* EMISSION FUNCTION Popt/I

.PARAM IPR={ITH*(1+1.1E-4*(TEMP-T0+dT)**2)}

.PARAM A1={98.572-5.14E-2*(TEMP-27+dT)}

+A2={6.8351E3-85.92*(TEMP-27+dT)}

+A3={-6.5015E5+5214.3*(TEMP-27+dT)}

G_OPT GNO OOU VALUE={IF(V(LA,GNO)<IPR,

+0,K*(A1*(V(LA,GNO)-IPR)+A2*((V(LA,GNO)-IPR)**2)+A3*((V(LA,GNO)-IPR)**3)))}

R_OPT OOU 0 1K

* TEMPEREATURE GROWTH OF SELFHEATING dT

G_T GNO TOU VALUE={ABS(V(21,20)*V(20,KA))*RT}

R_T TOU GNO 1E6

C_T TOU GNO 50N

.PARAM dT=7 RT=900

* RT - thermal resistance junction/case [oC/W]

* C_T - averaging capacitor C_T[nF]=1*t[ns]

* t - final time value for transient analysis

* .IC V(TOU,GNO)=0 - initial condition for proper calculation of dT using transient analysis

.ENDS

4. Illustrative simulations and measurement verification.

In the next figures some examples of dynamic pulse simulations and oscillograms are presented. The signal of the driver (upper curves) has been approximated in simulations by frequently applied in SPICE PWL (piece wise linear) manner and additionally sharp folds of the PWL were smoothed in simulations by 3-th order Thomson filter . The optical responses are shown in lower curves.

Fig.3. Oscillogram – near threshold driving

Fig.4. Simulation – near threshold driving

Fig.5. Oscillogram-square wave

Fig.6. Simulation-square wave

5. Conclusions.

Semiconductor lasers similarly as the other semiconductor components have wide spread of their important parameters from piece to piece. The exact modeling of such components needs of measuring of the substantial components and entering actual parameters to circuit file. From measurements and simulations was found that in the case of VCSEL there are two most important parameters:

· threshold current I_Th

· average slope of static characteristic (above threshold) K=dP/dI.

In all measurements presented in the article laser receptacle was optically coupled to photodiode via graded index fiber 62.5/125 mm and for such connection K was determined. Moreover determination of the temperature of minimal threshold current, however troublesome, has important influence on the precision of modeling and is recommended. Reader would notice that important equation (1) is valid only for certain class of VCSELs but the structure of the model allows to change the thermal dependence of the treshold current via modifications of one line:

.PARAM IPR={ITH*(1+1.1E-4*(TEMP-T0+dT)**2)} for other lasers.

All important parameters are placed in the separated text lines .PARAM of the subcircuit file so that any modifications are easy to make.

References

[1] Specifications of TFC-M85A4X5

Lasermate, www.lasermate.com

[2] M.S.Shur

PPI VCSEL Model Released in Smart Spice

Journal for Circ.Simul. and SPICE Modeling Engineers Vol.13 No.4 Apr. 2003

[3] J.Guenter, J.Tatum,K.Johnson

Honeywell Optoelectronic Application, www.advancedopticalcomponents.com

Modulation Advanced Optical Components-Oxide VCSELs

[4] VCSEL SPICE model

Honeywell Optoelectronic Application, www.advancedopticalcomponents.com

[5] A.Wolczko

Circuit makes universal VCSEL driver EDN July 10/2003 p.78¸80

[6] J.Tatum, D.Smith, J.Guenter, R.Johnson

High Speed Characteristics of VCSELs

Honeywell Optoelectronic Application, www.advancedopticalcomponents.com

Technical College - Bourgas,